plugins {
    id 'com.android.application' version '9.1.1' apply false
    id 'com.google.gms.google-services' version '4.4.4' apply false
    id 'io.sentry.android.gradle' version '6.8.1' apply false
    id 'org.lsposed.lsparanoid' version '0.5.2'
}

subprojects {
    afterEvaluate {
        if (plugins.hasPlugin("com.android.library") ||
                plugins.hasPlugin("com.android.application")) {
            android {
                compileSdkVersion 36
                buildToolsVersion "36.1.0"
                ndkVersion "28.0.13004108"

                lint {
                    checkReleaseBuilds false
                    disable 'MissingTranslation', 'ExtraTranslation', 'BlockedPrivateApi'
                }

                compileOptions {
                    sourceCompatibility JavaVersion.VERSION_21
                    targetCompatibility JavaVersion.VERSION_21

                    coreLibraryDesugaringEnabled true
                }

                defaultConfig {
                    minSdkVersion 23
                    targetSdkVersion 36
                }

                buildTypes {
                    play {
                        initWith release
                    }
                }

                buildFeatures.buildConfig = true
            }

            dependencies {
                coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs_nio:2.1.5'
            }
        }
    }
}